kotlin/libraries/tools/kotlin-sam-with-receiver/build.gradle

apply plugin: 'kotlin'
apply plugin: 'jps-compatible'

configureJvmProject(project)
configurePublishing(project)

compileJava {
    sourceCompatibility = 1.8
    targetCompatibility = 1.8
    options.fork = false
}

pill {
    variant = 'FULL'
}

repositories {
    mavenLocal()
    jcenter()
}

dependencies {
    compile project(':kotlin-gradle-plugin-api')
    compile project(':kotlin-gradle-plugin-model')

    compile kotlinStdlib()
    compileOnly project(':compiler')
    compileOnly project(':kotlin-sam-with-receiver-compiler-plugin')

    compileOnly gradleApi()

    testCompile gradleApi()
    testCompile "junit:junit:4.12"
}

evaluationDependsOn(":kotlin-sam-with-receiver-compiler-plugin")

tasks.withType(project.compileKotlin.class) {
    kotlinOptions.languageVersion = "1.2"
    kotlinOptions.apiVersion = "1.2"
    kotlinOptions.freeCompilerArgs += ["-Xskip-metadata-version-check"]
}

jar {
    from(project(":kotlin-sam-with-receiver-compiler-plugin").sourceSets.main.output.classesDirs)
    from(project(":kotlin-sam-with-receiver-compiler-plugin").sourceSets.main.output.resourcesDir)
    manifestAttributes(manifest, project)
}

ArtifactsKt.runtimeJar(project, EmbeddableKt.rewriteDepsToShadedCompiler(project, jar, {}), {})

artifacts {
    archives sourcesJar
}

javadocJar()

test.executable = "${JDK_18}/bin/java"