/*
 * SPDX-License-Identifier: Apache-2.0
 *
 * Copyright 2020-2021 The JReleaser authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
package org.jreleaser.gradle.plugin.internal.dsl

import groovy.transform.CompileStatic
import org.gradle.api.Action
import org.gradle.api.NamedDomainObjectContainer
import org.gradle.api.NamedDomainObjectFactory
import org.gradle.api.file.DirectoryProperty
import org.gradle.api.internal.provider.Providers
import org.gradle.api.model.ObjectFactory
import org.gradle.api.tasks.Internal
import org.jreleaser.gradle.plugin.dsl.Article
import org.jreleaser.gradle.plugin.dsl.Artifact
import org.jreleaser.gradle.plugin.dsl.CommitAuthor
import org.jreleaser.gradle.plugin.dsl.Tap
import org.kordamp.gradle.util.ConfigureUtil

import javax.inject.Inject

/**
 *
 * @author Andres Almiray
 * @since 0.6.0
 */
@CompileStatic
class ArticleImpl extends AbstractAnnouncer implements Article {
    private final NamedDomainObjectContainer<ArtifactImpl> files
    final DirectoryProperty templateDirectory
    final TapImpl repository
    final CommitAuthorImpl commitAuthor

    @Inject
    ArticleImpl(ObjectFactory objects) {
        super(objects)

        files = objects.domainObjectContainer(ArtifactImpl, new NamedDomainObjectFactory<ArtifactImpl>() {
            @Override
            ArtifactImpl create(String name) {
                ArtifactImpl artifact = objects.newInstance(ArtifactImpl, objects)
                artifact.name = name
                artifact
            }
        })

        templateDirectory = objects.directoryProperty().convention(Providers.notDefined())
        repository = objects.newInstance(TapImpl, objects)
        commitAuthor = objects.newInstance(CommitAuthorImpl, objects)
    }

    @Override
    void file(Action<? super Artifact> action) {
        action.execute(files.maybeCreate("files-${files.size()}".toString()))
    }

    @Override
    void file(@DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = Artifact) Closure<Void> action) {
        ConfigureUtil.configure(action, files.maybeCreate("files-${files.size()}".toString()))
    }


    @Override
    void repository(Action<? super Tap> action) {
        action.execute(repository)
    }

    @Override
    void commitAuthor(Action<? super CommitAuthor> action) {
        action.execute(commitAuthor)
    }

    @Override
    void repository(@DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = Tap) Closure<Void> action) {
        ConfigureUtil.configure(action, repository)
    }

    @Override
    void commitAuthor(@DelegatesTo(strategy = Closure.DELEGATE_FIRST, value = CommitAuthor) Closure<Void> action) {
        ConfigureUtil.configure(action, commitAuthor)
    }

    @Override
    @Internal
    boolean isSet() {
        super.isSet() ||
            !files.isEmpty()
        templateDirectory.present ||
            repository.isSet() ||
            commitAuthor.isSet()
    }

    org.jreleaser.model.Article toModel() {
        org.jreleaser.model.Article article = new org.jreleaser.model.Article()
        fillProperties(article)

        for (ArtifactImpl file : files) {
            article.addFile(file.toModel())
        }

        if (templateDirectory.present) {
            article.templateDirectory = templateDirectory.get().asFile.toPath().toAbsolutePath().toString()
        }

        if (repository.isSet()) article.repository = repository.toRepository()
        if (commitAuthor.isSet()) article.commitAuthor = commitAuthor.toModel()

        article
    }
}
